Вывод точки по таблице.

 Сейчас хотелось бы поговорить о выводе точки. Сразу скажу, что метод, предложенный SATSOFT'ом в седьмом номере BODY, меня не вполне устраивает из-за скорости работы. Думаю, это связано с тем, что при подготовке BODY не всегда учитывались материалы из других изданий, где можно найти немало полезной информации, в частности в ECHO#1.

 Именно о процедуре вывода точки из ECHO я и хочу рассказать. Почему я решил снова её опубликовать? Причина проста: в ECHO подпрограмма вывода точки была напечатана с ошибкой. Кроме того, здесь я приведу процедуру создания таблицы, необходимой для её работы.

 Вывод точки:

	LD      D,XPOSITION
	LD      B,YPOSITION
	LD      H,СТАРШИЙ БАЙТ АДРЕСА ТАБЛИЦЫ
	LD      L,D
	LD      E,(HL)
	INC     H
	LD      A,(HL)
	LD      L,B
	INC     H
	OR      (HL)
	LD      C,A
	INC     H
	LD      B,(HL)
	LD      A,(BC)
	OR      E
	LD      (BC),A

	LD H,СТАРШИЙ БАЙТ РАЗМЕЩЕНИЯ БУДУЩЕЙ ТАБЛИЦЫ
	LD L,0
	LD A,1
	LD B,L
	MET1    RRCA
	        LD (HL),A
	        INC HL
	        DJNZ MET1
	LD D,L
	LD B,D
	MET2    LD A,D
	        RRCA
	        RRCA
	        RRCA
	        AND 31
	        LD (HL),A
	        INC HL
	        INC D
	        DJNZ MET2
	LD B,192
	MET3    LD A,D
	        RLCA
	        RLCA
	        AND 224
	        LD (HL),A
	        LD A,D
	        AND 7
	        LD E,A
	        LD A,D
	        AND 192
	        RRCA
	        RRCA
	        RRCA
	        OR 64
	        OR E
	        INC H
	        LD (HL),A
	        DEC H
	        INC HL
	        INC D
	        DJNZ MET3
	        RET

	Y  ▒▒▓▓▓░░░      X  ╬╬╬╬╬+++
	   76543210         76543210

	Полученный адрес:

	010▒▒░░░ ▓▓▓╬╬╬╬╬
	76543210 76543210
	    │         │
	    │         └─ младший байт адреса
	    └─────────── старший байт адреса